La svastica sul sole, Philip K. Dick

La svastica sul sole
Di Philip K. Dick
Editore: Fanucci


Lingua: Italiano | Numero di pagine: 336 | Isbn-10: 8834710878 | Data di pubblicazione: 01/01/2005 | Traduttore: Maurizio Nati | Curatore: Carlo Pagetti | Genere: Narrativa & Letteratura - Storia - Fantascienza

Sour adj

/ˈsaʊə/

Traducendo Unreal Estate ho imparato questo vocabolo.

English		Italiano
sour adj	(taste: acidic)	aspro, acido agg
	Jane grimaced as she tasted the sour lemon.
	Jane fece una smorfia quando assaggiò il limone aspro.
sour adj	figurative (bitter, resentful)	aspro, acido agg
	After a number of disappointments early in her life, Ann had become sour.
	Dopo una quantità di delusioni nella vita, Ann era diventata amareggiata.
sour vi	(turn bad)	inacidirsi, rovinarsi, guastarsi v rif
	The milk soured because Ben forgot to put it back in the fridge.
	Il latte inacidì perché Ben dimenticò di rimetterlo nel frigorifero.

They suffered with me for two years in a job turned sour, encouraging me to jump ship and bring this dream to life.

Hanno sofferto con me per due anni a causa di un rapporto lavorativo rovinato, incoraggiandomi ad abbandonarlo e a dare vita a questo sogno.

Revival, Stephen King

Revival
Di Stephen King
Editore: Sperling & Kupfer (Pandora)


Lingua: Italiano | Numero di pagine: 480 | Isbn-13: 9788820057916 | Data di pubblicazione: 17/03/2015 | Traduttore: Giovanni Arduino | Genere: Narrativa & Letteratura - Horror - Mistero & Gialli

Selezione multipla di Unità Organizzative

*----------------------------------------------------------------------*
* DECLARATIONS                                                         *
*----------------------------------------------------------------------*
TABLES: pa0001, sscrfields.

DATA: gv_plvar TYPE plvar.                                

*----------------------------------------------------------------------*
* LAYOUT                                                               *
*----------------------------------------------------------------------*
SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME TITLE TEXT-001.
SELECT-OPTIONS: so_orgeh FOR pa0001-orgeh.
SELECTION-SCREEN: BEGIN OF LINE,
                  PUSHBUTTON 33(47) pb_orgmc USER-COMMAND comm01,
                  END OF LINE.
SELECTION-SCREEN END OF BLOCK b1.

*----------------------------------------------------------------------*
* EVENTS                                                               *
*----------------------------------------------------------------------*
AT SELECTION-SCREEN.
  DATA: lt_sel_hrobject TYPE TABLE OF hrobject,
        ls_sel_hrobject TYPE hrobject.
  IF gv_plvar IS INITIAL.
  CALL FUNCTION 'RH_GET_PLVAR'
    IMPORTING
      plvar = gv_plvar.
  ENDIF.
  CASE sscrfields-ucomm.
    WHEN 'COMM01'.
      CALL FUNCTION 'RH_OBJID_REQUEST'
        EXPORTING
          plvar            = gv_plvar
          otype            = 'O'
          seark_begda      = sy-datum
          seark_endda      = sy-datum
          set_mode         = 'X'
        TABLES
          sel_hrobject_tab = lt_sel_hrobject
        EXCEPTIONS
          cancelled        = 1
          wrong_condition  = 2
          nothing_found    = 3
          illegal_mode     = 4
          internal_error   = 5
          OTHERS           = 6.
      IF sy-subrc = 0.
        so_orgeh-sign = 'I'.
        so_orgeh-option = 'EQ'.
        LOOP AT lt_sel_hrobject INTO ls_sel_hrobject.
          so_orgeh-low = ls_sel_hrobject-objid.
          APPEND so_orgeh.
        ENDLOOP.
      ENDIF.
  ENDCASE.

*----------------------------------------------------------------------*
* INIT                                                                 *
*----------------------------------------------------------------------*
INITIALIZATION.
  pb_orgmc = 'Selezione multipla UO'.

*----------------------------------------------------------------------*

Mapping dinamico da Excel a BAPI per creazione cespiti

*----------------------------------------------------------------------*
* FORM MAPPING_AND_BAPI                                                *
*----------------------------------------------------------------------*
FORM mapping_and_bapi.

  FIELD-SYMBOLS: <lf_tabella> TYPE table,
                 <lf_riga>    TYPE any,
                 <lf_campo>   TYPE any.

  DATA: ls_anlu             TYPE anlu,
        ls_item             TYPE soi_generic_item,
        lv_tf               TYPE string,
        lv_tfx              TYPE string,
        lv_field            TYPE string,
        lv_dtype            TYPE c,
        lv_area             TYPE bf_afabe_d,
        lt_exception_list   TYPE TABLE OF rsexc,
        lt_export_parameter TYPE TABLE OF rsexp,
        lt_import_parameter TYPE TABLE OF rsimp,
        lt_tables_parameter TYPE TABLE OF rstbl,
        ls_tables_parameter TYPE rstbl.

*import
  DATA: ls_key                  TYPE bapi1022_key,
        lv_createsubnumber      TYPE xsubno,
        ls_generaldata          TYPE bapi1022_feglg001,
        ls_generaldatax         TYPE bapi1022_feglg001x,
        ls_inventory            TYPE bapi1022_feglg011,
        ls_inventoryx           TYPE bapi1022_feglg011x,
        ls_postinginformation   TYPE bapi1022_feglg002,
        ls_postinginformationx  TYPE bapi1022_feglg002x,
        ls_timedependentdata    TYPE bapi1022_feglg003,
        ls_timedependentdatax   TYPE bapi1022_feglg003x,
        ls_allocations          TYPE bapi1022_feglg004,
        ls_allocationsx         TYPE bapi1022_feglg004x,
        ls_origin               TYPE bapi1022_feglg009,
        ls_originx              TYPE bapi1022_feglg009x,
        ls_investacctassignmnt  TYPE bapi1022_feglg010,
        ls_investacctassignmntx TYPE bapi1022_feglg010x.
*export
  DATA: lv_companycode  TYPE bapi1022_1-comp_code,
        lv_asset        TYPE bapi1022_1-assetmaino,
        lv_subnumber    TYPE bapi1022_1-assetsubno,
        ls_assetcreated TYPE bapi1022_reference.
*tables
  DATA: lt_depreciationareas  TYPE TABLE OF bapi1022_dep_areas,
        ls_depreciationareas  TYPE bapi1022_dep_areas,
        lt_depreciationareasx TYPE TABLE OF bapi1022_dep_areasx,
        ls_depreciationareasx TYPE bapi1022_dep_areasx,
        lt_cumulatedvalues    TYPE TABLE OF bapi1022_cumval,
        ls_cumulatedvalues    TYPE bapi1022_cumval,
        lt_return             TYPE TABLE OF bapiret2,
        ls_return             TYPE bapiret2.

  CALL FUNCTION 'FUNCTION_IMPORT_INTERFACE'
    EXPORTING
      funcname           = 'BAPI_FIXEDASSET_OVRTAKE_CREATE'
    TABLES
      exception_list     = lt_exception_list
      export_parameter   = lt_export_parameter
      import_parameter   = lt_import_parameter
      tables_parameter   = lt_tables_parameter
    EXCEPTIONS
      error_message      = 1
      function_not_found = 2
      invalid_name       = 3
      OTHERS             = 4.
  IF sy-subrc <> 0.
* Implement suitable error handling here
  ENDIF.

  LOOP AT gt_data INTO gs_data.
    READ TABLE gt_head INTO ls_item WITH KEY row = '1'
                                             column = gs_data-column.
    READ TABLE lt_tables_parameter
          INTO ls_tables_parameter
      WITH KEY parameter = ls_item-value.
    IF sy-subrc <> 0.
*exporting
      IF ls_item-value = 'CREATESUBNUMBER'.
        lv_tf = 'LV_CREATESUBNUMBER'.
      ELSE.
        CONCATENATE 'LS_' ls_item-value INTO lv_tf.
        CONCATENATE 'LS_' ls_item-value 'X' INTO lv_tfx.
        READ TABLE gt_head INTO ls_item WITH KEY row = '2'
                                                 column = gs_data-column.
        CONCATENATE lv_tf '-' ls_item-value INTO lv_tf.
        IF ls_item-value = 'PLATE_NO'.
          CONCATENATE lv_tfx '-' 'LICENSE_PLATE_NO' INTO lv_tfx.
        ELSEIF ls_item-value = 'ORIG_ACQ_YR'.
          CONCATENATE lv_tfx '-' 'ORIG_ACQ_YEAR' INTO lv_tfx.
        ELSE.
          CONCATENATE lv_tfx '-' ls_item-value INTO lv_tfx.
        ENDIF.
      ENDIF.
      IF lv_tf = 'LS_ORIGIN-ORIG_ACQ_YR'.
        IF gs_data-value IS NOT INITIAL.
          ls_origin-orig_acq_yr = gs_data-value+6(4).
        ENDIF.
      ELSEIF lv_tf = 'LS_ORIGIN-PURCH_NEW'.
        IF gs_data-value = 'X'.
          CLEAR ls_origin-purch_new.
        ELSE.
          ls_origin-purch_new = 'X'.
        ENDIF.
      ELSE.
        ASSIGN (lv_tf) TO <lf_campo>.
        IF <lf_campo> IS ASSIGNED.
          DESCRIBE FIELD <lf_campo> TYPE lv_dtype.
          CASE lv_dtype.
            WHEN 'D'.
              CONCATENATE gs_data-value+6(4)
                          gs_data-value+3(2)
                          gs_data-value+0(2)
                     INTO <lf_campo>.
            WHEN 'P'.
              TRANSLATE gs_data-value USING ',.'.
              <lf_campo> = gs_data-value.
            WHEN OTHERS.
              <lf_campo> = gs_data-value.
          ENDCASE.
          UNASSIGN <lf_campo>.
        ENDIF.
      ENDIF.
      ASSIGN (lv_tfx) TO <lf_campo>.
      IF <lf_campo> IS ASSIGNED.
        <lf_campo> = 'X'.
        UNASSIGN <lf_campo>.
      ENDIF.
    ELSE.
*tables
      CONCATENATE 'LT_' ls_item-value INTO lv_tf.
      CONCATENATE 'LT_' ls_item-value 'X' INTO lv_tfx.
      ASSIGN (lv_tf) TO <lf_tabella>.
      READ TABLE gt_head INTO ls_item WITH KEY row = '2'
                                               column = gs_data-column.
      lv_area = ls_item-value(2).
      SHIFT ls_item-value BY 3 PLACES.
      lv_field = 'AREA'.
      READ TABLE <lf_tabella> ASSIGNING <lf_riga>
        WITH KEY (lv_field) = lv_area.
      IF sy-subrc <> 0.
        APPEND INITIAL LINE TO <lf_tabella> ASSIGNING <lf_riga>.
        ASSIGN COMPONENT lv_field OF STRUCTURE <lf_riga> TO <lf_campo>.
        IF <lf_campo> IS ASSIGNED.
          <lf_campo> = lv_area.
          UNASSIGN <lf_campo>.
        ENDIF.
        lv_field = 'FISC_YEAR'.
        ASSIGN COMPONENT lv_field OF STRUCTURE <lf_riga> TO <lf_campo>.
        IF <lf_campo> IS ASSIGNED.
          <lf_campo> = pa_fiscy.
          UNASSIGN <lf_campo>.
        ENDIF.
        lv_field = 'ACQ_VALUE'.
        ASSIGN COMPONENT lv_field OF STRUCTURE <lf_riga> TO <lf_campo>.
        IF <lf_campo> IS ASSIGNED.
          TRANSLATE gs_data-value USING ',.'.
          <lf_campo> = gs_data-value.
          UNASSIGN <lf_campo>.
        ENDIF.
        UNASSIGN: <lf_tabella>, <lf_riga>, <lf_campo>.
        ASSIGN (lv_tfx) TO <lf_tabella>.
        IF <lf_tabella> IS ASSIGNED.
          APPEND INITIAL LINE TO <lf_tabella> ASSIGNING <lf_riga>.
          ASSIGN COMPONENT ls_item-value OF STRUCTURE <lf_riga> TO <lf_campo>.
          <lf_campo> = lv_area.
          UNASSIGN: <lf_tabella>, <lf_riga>, <lf_campo>.
        ENDIF.
      ELSE.
        ASSIGN COMPONENT ls_item-value OF STRUCTURE <lf_riga> TO <lf_campo>.
        IF <lf_campo> IS ASSIGNED.
          DESCRIBE FIELD <lf_campo> TYPE lv_dtype.
          CASE lv_dtype.
            WHEN 'D'.
              CONCATENATE gs_data-value+6(4)
                          gs_data-value+3(2)
                          gs_data-value+0(2)
                     INTO <lf_campo>.
            WHEN 'P'.
              TRANSLATE gs_data-value USING ',.'.
              <lf_campo> = gs_data-value.
            WHEN OTHERS.
              <lf_campo> = gs_data-value.
          ENDCASE.
          UNASSIGN: <lf_tabella>, <lf_riga>, <lf_campo>.
        ENDIF.
        ASSIGN (lv_tfx) TO <lf_tabella>.
        IF <lf_tabella> IS ASSIGNED.
          lv_field = 'AREA'.
          READ TABLE <lf_tabella> ASSIGNING <lf_riga>
            WITH KEY (lv_field) = lv_area.
          ASSIGN COMPONENT ls_item-value OF STRUCTURE <lf_riga> TO <lf_campo>.
          IF <lf_campo> IS ASSIGNED.
            <lf_campo> = 'X'.
            UNASSIGN: <lf_tabella>, <lf_riga>, <lf_campo>.
          ENDIF.
        ENDIF.
      ENDIF.
    ENDIF.
    AT END OF row.
      LOOP AT lt_depreciationareas
         INTO ls_depreciationareas WHERE deactivate = 'X'.
        DELETE lt_cumulatedvalues WHERE area = ls_depreciationareas-area.
      ENDLOOP.
*elimino se presenti le area da copiare
      LOOP AT so_aree.
        READ TABLE lt_depreciationareas
              INTO ls_depreciationareas
          WITH KEY area = so_aree-high.
        IF sy-subrc = 0.
          DELETE TABLE lt_depreciationareas FROM ls_depreciationareas.
          READ TABLE lt_depreciationareasx
                INTO ls_depreciationareasx
            WITH KEY area = so_aree-high.
          DELETE TABLE lt_depreciationareasx FROM ls_depreciationareasx.
        ENDIF.
        READ TABLE lt_cumulatedvalues
              INTO ls_cumulatedvalues
          WITH KEY area = so_aree-high.
        IF sy-subrc = 0.
          DELETE TABLE lt_cumulatedvalues FROM ls_cumulatedvalues.
        ENDIF.
      ENDLOOP.
*copio le aree
      LOOP AT so_aree.
        READ TABLE lt_depreciationareas
              INTO ls_depreciationareas
          WITH KEY area = so_aree-low.
        IF sy-subrc = 0.
          ls_depreciationareas-area = so_aree-high.
          APPEND ls_depreciationareas TO lt_depreciationareas.
          READ TABLE lt_depreciationareasx
                INTO ls_depreciationareasx
            WITH KEY area = so_aree-low.
          ls_depreciationareasx-area = so_aree-high.
          APPEND ls_depreciationareasx TO lt_depreciationareasx.
        ENDIF.
        READ TABLE lt_cumulatedvalues
              INTO ls_cumulatedvalues
          WITH KEY area = so_aree-low.
        IF sy-subrc = 0.
          ls_cumulatedvalues-area = so_aree-high.
          APPEND ls_cumulatedvalues TO lt_cumulatedvalues.
        ENDIF.
      ENDLOOP.
      DO.
        SORT: lt_depreciationareas,
              lt_depreciationareasx,
              lt_cumulatedvalues.
        CALL FUNCTION 'BAPI_FIXEDASSET_OVRTAKE_CREATE'
          EXPORTING
            key                  = ls_key
            createsubnumber      = lv_createsubnumber
            testrun              = cb_test
            generaldata          = ls_generaldata
            generaldatax         = ls_generaldatax
            inventory            = ls_inventory
            inventoryx           = ls_inventoryx
            postinginformation   = ls_postinginformation
            postinginformationx  = ls_postinginformationx
            timedependentdata    = ls_timedependentdata
            timedependentdatax   = ls_timedependentdatax
            allocations          = ls_allocations
            allocationsx         = ls_allocationsx
            origin               = ls_origin
            originx              = ls_originx
            investacctassignmnt  = ls_investacctassignmnt
            investacctassignmntx = ls_investacctassignmntx
          IMPORTING
            companycode          = lv_companycode
            asset                = lv_asset
            subnumber            = lv_subnumber
            assetcreated         = ls_assetcreated
          TABLES
            depreciationareas    = lt_depreciationareas
            depreciationareasx   = lt_depreciationareasx
            cumulatedvalues      = lt_cumulatedvalues
            return               = lt_return.
        READ TABLE lt_return
              INTO ls_return
          WITH KEY type = 'E'
                   id = 'AY'
                   number = '221'.
        IF sy-subrc = 0.
          DELETE lt_depreciationareas WHERE deactivate = 'X'.
          DELETE lt_depreciationareasx WHERE deactivate = 'X'.
          CLEAR lt_return[].
        ELSE.
          COMMIT WORK AND WAIT.
          EXIT.
        ENDIF.
      ENDDO.
      IF lv_asset IS NOT INITIAL AND cb_test IS INITIAL.
        ls_anlu-bukrs = lv_companycode.
        ls_anlu-anln1 = lv_asset.
        ls_anlu-anln2 = lv_subnumber.
        MODIFY anlu FROM ls_anlu.
        LOOP AT lt_depreciationareas INTO ls_depreciationareas
                                     WHERE deactivate <> 'X'.
          UPDATE anlb
             SET afabg = ls_depreciationareas-odep_start_date
           WHERE bukrs = lv_companycode
             AND anln1 = lv_asset
             AND anln2 = lv_subnumber
             AND afabe = ls_depreciationareas-area
             AND bdatu = '99991231'.
        ENDLOOP.
      ENDIF.
      LOOP AT lt_return INTO ls_return.
        ls_return-row = gs_data-row.
        APPEND ls_return TO gt_return.
      ENDLOOP.
      CLEAR: ls_anlu,
             ls_key,
             lv_createsubnumber,
             ls_generaldata,
             ls_generaldatax,
             ls_inventory,
             ls_inventoryx,
             ls_postinginformation,
             ls_postinginformationx,
             ls_timedependentdata,
             ls_timedependentdatax,
             ls_allocations,
             ls_allocationsx,
             ls_origin,
             ls_originx,
             ls_investacctassignmnt,
             ls_investacctassignmntx,
             lv_companycode,
             lv_asset,
             lv_subnumber,
             ls_assetcreated,
             lt_depreciationareas[],
             ls_depreciationareas,
             lt_depreciationareasx[],
             ls_depreciationareasx,
             lt_cumulatedvalues[],
             ls_cumulatedvalues,
             lt_return[],
             ls_return.
    ENDAT.
  ENDLOOP.

ENDFORM.

*----------------------------------------------------------------------*

Creare un semplice cruscotto

*----------------------------------------------------------------------*
* DECLARATIONS                                                         *
*----------------------------------------------------------------------*
TABLES: sscrfields.

*----------------------------------------------------------------------*
* LAYOUT                                                               *
*----------------------------------------------------------------------*
SELECTION-SCREEN BEGIN OF BLOCK b1 WITH FRAME TITLE TEXT-001.
SELECTION-SCREEN: BEGIN OF LINE,
                  PUSHBUTTON 1(4) pb_uvet USER-COMMAND comm01,
                  COMMENT 6(79) TEXT-d11,
                  END OF LINE.
SELECTION-SCREEN END OF BLOCK b1.

SELECTION-SCREEN BEGIN OF BLOCK b2 WITH FRAME TITLE TEXT-002.
SELECTION-SCREEN: BEGIN OF LINE,
                  PUSHBUTTON 1(4) pb_del USER-COMMAND comm02,
                  COMMENT 6(79) TEXT-d21,
                  END OF LINE.
SELECTION-SCREEN: BEGIN OF LINE,
                  COMMENT 6(79) TEXT-d22 MODIF ID id1,
                  END OF LINE.
SELECTION-SCREEN: BEGIN OF LINE,
                  PUSHBUTTON 1(4) pb_del2 USER-COMMAND comm10,
                  COMMENT 6(79) TEXT-d23,
                  END OF LINE.
SELECTION-SCREEN: BEGIN OF LINE,
                  COMMENT 6(79) TEXT-d22 MODIF ID id1,
                  END OF LINE.
SELECTION-SCREEN SKIP.
SELECTION-SCREEN: BEGIN OF LINE,
                  PUSHBUTTON 1(4) pb_zint USER-COMMAND comm03,
                  COMMENT 6(79) TEXT-d31,
                  END OF LINE.
SELECTION-SCREEN: BEGIN OF LINE,
                  PUSHBUTTON 6(4) pb_check USER-COMMAND comm04,
                  COMMENT 11(79) TEXT-d41,
                  END OF LINE.
SELECTION-SCREEN: BEGIN OF LINE,
                  PUSHBUTTON 6(4) pb_appr USER-COMMAND comm05,
                  COMMENT 11(79) TEXT-d51,
                  END OF LINE.
SELECTION-SCREEN SKIP.
SELECTION-SCREEN: BEGIN OF LINE,
                  PUSHBUTTON 1(4) pb_exc USER-COMMAND comm06,
                  COMMENT 6(79) TEXT-d61,
                  END OF LINE.
SELECTION-SCREEN END OF BLOCK b2.

SELECTION-SCREEN BEGIN OF BLOCK b3 WITH FRAME TITLE TEXT-003.
SELECTION-SCREEN: BEGIN OF LINE,
                  PUSHBUTTON 1(4) pb_inter USER-COMMAND comm07,
                  COMMENT 6(79) TEXT-d71,
                  END OF LINE.
SELECTION-SCREEN: BEGIN OF LINE,
                  PUSHBUTTON 1(4) pb_forn USER-COMMAND comm08,
                  COMMENT 6(79) TEXT-d81,
                  END OF LINE.
SELECTION-SCREEN: BEGIN OF LINE,
                  PUSHBUTTON 1(4) pb_cdc USER-COMMAND comm09,
                  COMMENT 6(79) TEXT-d91,
                  END OF LINE.
SELECTION-SCREEN END OF BLOCK b3.

SELECTION-SCREEN BEGIN OF BLOCK b4 WITH FRAME TITLE TEXT-004.
SELECTION-SCREEN: BEGIN OF LINE,
                  PUSHBUTTON 1(4) pb_descr USER-COMMAND comm11,
                  COMMENT 6(79) TEXT-d92,
                  END OF LINE.
SELECTION-SCREEN END OF BLOCK b4.

*----------------------------------------------------------------------*
* EVENTS                                                               *
*----------------------------------------------------------------------*
AT SELECTION-SCREEN.
  CASE sscrfields-ucomm.
    WHEN 'COMM01'.
      CALL TRANSACTION 'ZHCM_ANAGR_UVET'.                
    WHEN 'COMM02'.
      CALL TRANSACTION 'ZHCM_ZT_ZINTORD_DEL'.            
    WHEN 'COMM10'.
      CALL TRANSACTION 'ZHCM_ZT_APPR_DEL'.               
    WHEN 'COMM03'.
      CALL TRANSACTION 'ZHCM_ZT_ZINTORD'.                
    WHEN 'COMM04'.
      CALL TRANSACTION 'ZHCM_IF_CHECK_OUT'.              
    WHEN 'COMM05'.
      CALL TRANSACTION 'ZHCM_APPR_IF_OUT'.               
    WHEN 'COMM06'.
      CALL TRANSACTION 'ZHCM_ZT_INTORD_E'.               
    WHEN 'COMM07'.
      CALL TRANSACTION 'ZHCM_INTERFACE_OUT'.             
    WHEN 'COMM08'.
      CALL TRANSACTION 'ZFBC_ESTR_FORN'.                 
    WHEN 'COMM09'.
      CALL TRANSACTION 'ZFBC_ESTR_CDC'.                  
    WHEN 'COMM11'.
      CALL TRANSACTION 'ZHCM_ZT_CHECK'.                  
  ENDCASE.

AT SELECTION-SCREEN OUTPUT.
  LOOP AT SCREEN.
    IF screen-group1 = 'ID1'.
      screen-intensified = 1.
      MODIFY SCREEN.
    ENDIF.
  ENDLOOP.

*----------------------------------------------------------------------*
* INIT                                                                 *
*----------------------------------------------------------------------*
INITIALIZATION.
  pb_uvet =
  pb_del =
  pb_del2 =
  pb_zint =
  pb_check =
  pb_appr =
  pb_exc =
  pb_inter =
  pb_forn  =
  pb_cdc =
  pb_descr = '@15@'.

*----------------------------------------------------------------------*
* PROGRAM BODY                                                         *
*----------------------------------------------------------------------*
START-OF-SELECTION.

END-OF-SELECTION.
  RETURN.

*----------------------------------------------------------------------*

Portcullis n

/pɔːtˈkʌlɪs/

Traducendo Perdition's Mouth: Abyssal Rift ho imparato questo vocabolo.

English		Italiano
portcullis n	(castle gate that is raised and lowered)	saracinesca nf

Closed portcullises do not block Area Effect attacks, but can be hit and destroyed by one.

Le saracinesche chiuse non bloccano gli attacchi a Effetto d’Area, ma possono essere colpite e distrutte da uno di essi.